[VB6-Source] Transparente Fenster
Weiß nicht ob es das hier schon gibt aber ich Persönlich finde es immer ganz nett wenn ein Programm ein bischen Transparent ist.
Hier ein bespiel:
http://img174.imageshack.us/img174/3...sperentcz0.jpg
Eigentlich ist diese Nette Funktion ziemlich einfach zu realiesieren, als erstes müsst ihr ein Modul anlegen, in den kommt dann dieser Code
Code:
Option Explicit
Declare Function GetWindowLong Lib "user32.dll" _
Alias "GetWindowLongA" ( _
ByVal hWnd As Long, _
ByVal nIndex As Long) As Long
Declare Function SetWindowLong Lib "user32.dll" _
Alias "SetWindowLongA" ( _
ByVal hWnd As Long, _
ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long
Declare Function SetLayeredWindowAttributes Lib "user32.dll" ( _
ByVal hWnd As Long, _
ByVal crKey As Long, _
ByVal bAlpha As Byte, _
ByVal dwFlags As Long) As Long
Public Const GWL_EXSTYLE = (-20)
Public Const WS_EX_LAYERED = &H80000
'Macht nur eine Farbe transparent
'Public Const LWA_COLORKEY = &H1
'Macht das ganze Fenster transparent
Public Const LWA_ALPHA = &H2
Public Sub Mache_Transparent(hWnd As Long, Rate As Byte)
'### funktioniert nur unter Windows 2000 oder XP!!!
'### macht das Fenster, dessen hWnd übergeben wurde, transparent
'### Rate: 254 = normal 0 = ganz transparent (also unsichtbar)
'### 190 ist z.B. ein guter Wert
Dim WinInfo As Long
WinInfo = GetWindowLong(hWnd, GWL_EXSTYLE)
If Rate < 255 Then
WinInfo = WinInfo Or WS_EX_LAYERED
SetWindowLong hWnd, GWL_EXSTYLE, WinInfo
SetLayeredWindowAttributes hWnd, 0, Rate, LWA_ALPHA
Else
'Wenn als Rate 255 angegeben wird,
'so wird der Ausgangszustand wiederhergestellt
WinInfo = WinInfo Xor WS_EX_LAYERED
SetWindowLong hWnd, GWL_EXSTYLE, WinInfo
End If
End Sub
So und damit ihr den dann in eurer Form aktivieren könnt muss noch der Code
Code:
Private Sub Form_Load()
Call Mache_Transparent(Me.hWnd, 190) ' Macht das fenster Transperent, 190 ist ein guter wert
End Sub
einfügen.
Wahlweise könnt ihr das natürlich auch auf zwei Button legen wobei ihr immer bedenken müsste das 0 = durchsichtig und 254 = normal ist :)
Hier ist das ganze sonst auch nochmal als vb6 projekt für die die z.B. nicht wissen wie man ein Modul erstellt
Hoffe euch gefällts, und bitte nicht rumjamern das der Code nicht von mir ist, er ist NICHT von mir habe ihn über google gefunden und dachte das ich ihn mit euch teile :)
Grüße
